Mercurial > minori

view dep/animone/configure.ac @ 258:862d0d8619f6

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
*: HUUUGE changes animia has been renamed to animone, so instead of thinking of a health condition, you think of a beautiful flower :) I've also edited some of the code for animone, but I have no idea if it even works or not because I don't have a mac or windows machine lying around. whoops! ... anyway, all of the changes divergent from Anisthesia are now licensed under BSD. it's possible that I could even rewrite most of the code to where I don't even have to keep the MIT license, but that's thinking too far into the future I've been slacking off on implementing the anime seasons page, mostly out of laziness. I think I'd have to create another db file specifically for the seasons anyway, this code is being pushed *primarily* because the hard drive it's on is failing! yay :)
author Paper <paper@paper.us.eu.org>
date Mon, 01 Apr 2024 02:43:44 -0400
parents
children 1a6a5d3a94cd
line wrap: on
line source

AC_INIT([animone], [0.1.0-alpha.1])

AC_CANONICAL_HOST

AC_CONFIG_SRCDIR([src/animone.cc])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIRS([m4])

AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])

# Do we have a C++17 compiler
AC_PROG_CXX

AM_PROG_AR
LT_INIT

build_win32=no
build_osx=no
build_linux=no
build_libutil=no
build_kvm=no

build_x11=no

case "${host_os}" in
	cygwin*|mingw*)
		# Windows
		build_windows=yes
		AC_CHECK_TOOL([WINDRES], [windres])
		AC_SUBST(WINDRES)
		AC_DEFINE([WIN32])
		;;
	darwin*)
		# Mac OS X
		build_osx=yes
		AC_DEFINE([MACOSX])
		;;
	linux*)
		build_linux=yes
		AC_DEFINE([LINUX])
		;;
	*)
		# FreeBSD
		AC_CHECK_LIB([util], [kinfo_getfile], [build_libutil=yes], [build_libutil=no])
		if test "x$build_libutil" = "xyes"; then
			AC_DEFINE([LIBUTIL])
		else
			# OpenBSD
			AC_CHECK_LIB([kvm], [kvm_getfiles], [build_kvm=yes], [build_kvm=no])
			if test "x$build_kvm" = "xyes"; then
				AC_DEFINE([LIBKVM])
			fi
		fi
		;;
esac

if test "x$build_osx" = "xno" && test "x$build_windows" = "xno"; then
	PKG_CHECK_MODULES(XCB, [xcb xcb-res], [build_x11=yes], [build_x11=no])
	if test "x$build_x11" = "xyes"; then
		AC_DEFINE([X11])
		AC_SUBST([XCB_LIBS])
		AC_SUBST([XCB_CFLAGS])
	fi
fi

AM_CONDITIONAL([BUILD_WIN], [test "x$build_windows" = "xyes"])
AM_CONDITIONAL([BUILD_OSX], [test "x$build_osx" = "xyes"])
AM_CONDITIONAL([BUILD_LINUX], [test "x$build_linux" = "xyes"])
AM_CONDITIONAL([BUILD_LIBUTIL], [test "x$build_libutil" = "xyes"])
AM_CONDITIONAL([BUILD_LIBKVM], [test "x$build_kvm" = "xyes"])

AM_CONDITIONAL([BUILD_XCB], [test "x$build_x11" = "xyes"])

AC_CONFIG_FILES([Makefile])
AC_OUTPUT