Mercurial > minori

view dep/animone/configure.ac @ 337:a7d4e5107531

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
dep/animone: REFACTOR ALL THE THINGS 1: animone now has its own syntax divergent from anisthesia, making different platforms actually have their own sections 2: process names in animone are now called `comm' (this will probably break things). this is what its called in bsd/linux so I'm just going to use it everywhere 3: the X11 code now checks for the existence of a UTF-8 window title and passes it if available 4: ANYTHING THATS NOT LINUX IS 100% UNTESTED AND CAN AND WILL BREAK! I still actually need to test the bsd code. to be honest I'm probably going to move all of the bsds into separate files because they're all essentially different operating systems at this point
author Paper <paper@paper.us.eu.org>
date Wed, 19 Jun 2024 12:51:15 -0400
parents a4257370de16
children f63dfa309380
line wrap: on
line source

AC_INIT([animone], [2.0.0])

AC_CANONICAL_HOST

AC_CONFIG_SRCDIR([src/animone.cc])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIRS([m4])

AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])

# Do we have a C++17 compiler
AC_PROG_CXX

AM_PROG_AR
LT_INIT

build_win32=no
build_osx=no
build_linux=no
build_libutil=no
build_kvm=no
build_bsd=no

build_x11=no

case "${host_os}" in
	cygwin*|mingw*)
		# Windows
		build_windows=yes
		AC_CHECK_TOOL([WINDRES], [windres])
		AC_SUBST(WINDRES)
		AC_DEFINE([USE_WIN32])
		;;
	darwin*)
		# Mac OS X
		build_osx=yes
		AC_DEFINE([USE_MACOSX])
		;;
	linux*)
		build_linux=yes
		AC_DEFINE([USE_LINUX])
		;;
	*)
		dnl BSDs
		AC_CHECK_LIB([util], [kinfo_getfile], [build_libutil=yes], [build_libutil=no])
		AC_CHECK_LIB([kvm], [kvm_getfiles], [build_kvm=yes], [build_kvm=no])

		if test "x$build_kvm" = "xyes"; then
			AC_DEFINE([USE_LIBKVM])
			AC_DEFINE([BSD])
		elif test "x$build_libutil" = "xyes"; then
			AC_DEFINE([USE_LIBUTIL])
			AC_DEFINE([BSD])
		fi
		;;
esac

if test "x$build_osx" != "xyes" && test "x$build_windows" != "xyes"; then
	PKG_CHECK_MODULES(XCB, [xcb xcb-res], [build_x11=yes], [build_x11=no])
	if test "x$build_x11" = "xyes"; then
		AC_DEFINE([USE_X11])
		AC_SUBST([XCB_LIBS])
		AC_SUBST([XCB_CFLAGS])
	fi
fi

AM_CONDITIONAL([BUILD_WIN], [test "x$build_windows" = "xyes"])
AM_CONDITIONAL([BUILD_OSX], [test "x$build_osx" = "xyes"])
AM_CONDITIONAL([BUILD_LINUX], [test "x$build_linux" = "xyes"])
AM_CONDITIONAL([BUILD_LIBUTIL], [test "x$build_libutil" = "xyes"])
AM_CONDITIONAL([BUILD_LIBKVM], [test "x$build_kvm" = "xyes"])
AM_CONDITIONAL([BUILD_BSD], [test "x$build_bsd" = "xyes"])

AM_CONDITIONAL([BUILD_XCB], [test "x$build_x11" = "xyes"])

AC_CONFIG_FILES([Makefile])
AC_OUTPUT