Mercurial > minori

view dep/animone/configure.ac @ 342:adb79bdde329

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
dep/animone: fix tons of issues for example, the window ID stuff was just... completely wrong. since we're supporting multiple different window systems, it *has* to be a union rather than just a single integer type. HWND is also not a DWORD, it's a pointer(!), so now it's stored as a std::uintptr_t. (this probably breaks things)
author Paper <paper@paper.us.eu.org>
date Thu, 20 Jun 2024 03:03:05 -0400
parents f63dfa309380
children
line wrap: on
line source

AC_INIT([animone], [0.2.0])

AC_CANONICAL_HOST

AC_CONFIG_SRCDIR([src/animone.cc])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIRS([m4])

AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])

# Do we have a C++17 compiler
AC_PROG_CXX

AM_PROG_AR
LT_INIT([win32-dll])

build_win32=no
build_osx=no
build_linux=no
build_libutil=no
build_kvm=no
build_bsd=no

build_x11=no

case "${host_os}" in
	cygwin*|mingw*)
		# Windows
		build_windows=yes
		AC_CHECK_TOOL([WINDRES], [windres])
		AC_SUBST(WINDRES)
		AC_DEFINE([USE_WIN32])
		;;
	darwin*)
		# Mac OS X
		build_osx=yes
		AC_DEFINE([USE_MACOSX])
		;;
	linux*)
		build_linux=yes
		AC_DEFINE([USE_LINUX])
		;;
	*)
		dnl BSDs
		saved_LIBS="$LIBS"
		AC_CHECK_LIB([util], [kinfo_getfile], [build_libutil=yes], [build_libutil=no])
		AC_CHECK_LIB([kvm], [kvm_getfiles], [build_kvm=yes], [build_kvm=no])
		LIBS="$saved_LIBS"

		if test "x$build_kvm" = "xyes"; then
			AC_DEFINE([USE_OPENBSD])
		elif test "x$build_libutil" = "xyes"; then
			AC_DEFINE([USE_FREEBSD])
		fi
		;;
esac

dnl todo: configure flag for this
if test "x$build_osx" != "xyes" && test "x$build_windows" != "xyes"; then
	PKG_CHECK_MODULES(XCB, [xcb xcb-res], [build_x11=yes], [build_x11=no])
	if test "x$build_x11" = "xyes"; then
		AC_DEFINE([USE_X11])
		AC_SUBST([XCB_LIBS])
		AC_SUBST([XCB_CFLAGS])
	fi
fi

AM_CONDITIONAL([BUILD_WIN], [test "x$build_windows" = "xyes"])
AM_CONDITIONAL([BUILD_OSX], [test "x$build_osx" = "xyes"])
AM_CONDITIONAL([BUILD_LINUX], [test "x$build_linux" = "xyes"])
AM_CONDITIONAL([BUILD_FREEBSD], [test "x$build_libutil" = "xyes"])
AM_CONDITIONAL([BUILD_OPENBSD], [test "x$build_kvm" = "xyes"])

AM_CONDITIONAL([BUILD_XCB], [test "x$build_x11" = "xyes"])

AC_CONFIG_FILES([Makefile])
AC_OUTPUT